***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 30, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PDZ10B A K 
.param
+vc0 = 1.046e-11	 vc1 = 8.826e-11	 vc2 = 1.000		 vc3 = 2.611e-13		 vc4 = 1.160
+tc1 = 9.081e-3		 tc2 = 1.091e-2		 tc3 = 5.701e-3		 tc4 = 4.021e-3
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 6.926e-16	   n = 1.017		  rs = 1.339e-1
+ibv = 5e-3		 nbv = 1.0		  bv = 9.99
+ikf = 3.604e-1
***** capacitance parameter *****
+cjo = 1.002e-10	   m = 3.183e-1		  vj = 5.816e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.113		 xti = 3
+trs1 = 2.056e-4	trs2 = -2.033e-6	tikf = 5.0e-3
+tbv1 = 5.877e-4	tbv2 = 2.446e-7	
.ends PDZ10B
*$
